# force_slow.cog
#
# A force power to slow down victims.
# Meant to replace blinding.
#
# [SM]
#======================================================================#
symbols

thing		player	local
thing		victim	local
thing		potential	local
thing		dummy	local
thing		target	local

int		rank		local
int		active	local
int		bin=27	local
int		mana	local

flex		cost=20	local
flex		maxDot	local
flex		dot		local
flex		timeleft	local
flex		mass	local

vector	vel			local
vector	momentum	local
vector	force		local

sound	slowsound=forceslow1.wav		local
sound	slowsound2=forceslow2.wav	local

template	cone_tpl=+force_blind			local

message	startup
message	activated
message	deactivated
message	pulse
message	timer
message	killed
message	selected

end
#======================================================================#
code
#----------------------------------------------------------------
startup:
	player=GetLocalPlayerThing();
	active=0;

Return;
#----------------------------------------------------------------
activated:
	if(active) Return;			// Return if the power is already in use.
	active=1;
	mana = GetInv(player, 14);
	rank = GetInv(player, bin);
	if(mana < cost) Return;		// Return if we don't have the mana.
	victim=-1;
	SetInvActivated(player, bin, 1);	// Show the icon.
	SetPulse(0.2);

Return;
#----------------------------------------------------------------
pulse:
	victim = -1;
	maxDot = 0;

	// Find the first player or actor in view of the player.
	potential = FirstThingInView(player, 30 + 15 * rank, 8, 0x404);

	// Loop until there are no more "next" things in view.
	while(potential != -1)
	{
		// Test the thing to see if it's: in sight, not the player, within range, not dead, not a droid, and not using persuasion if we have force vision off.
		if(HasLOS(player, potential) && potential != player && VectorDist(GetThingPos(player), GetThingPos(potential)) <= 1 + rank && !(GetThingFlags(potential) & 0x200) && !(GetActorFlags(potential) & 0x100) && !(jkGetFlags(potential) & 0x20 && !IsInvActivated(player, 23)))
		{
			// dot will be the dot product of the angle between the direction the player is looking and a direction from the player to the potential target.
			dot = ThingViewDot(player, potential);

			// If dot is greater than 0 or the dot of the last potential, then the new potential is closer to the center of the player's LOS.
			if(dot > maxDot)
			{
				// Store this target's number and remember the dot.
				victim = potential;
				maxDot = dot;
			}
		}

		// Get the next thing in view for the next loop.
		potential = NextThingInView();
	}

	// If victim is not equal to -1, then we've found an acceptable target.
	if(victim != -1)
	{
		// Set the reticle's colors and put it on the target.
		jkSetTargetColors(1, 2, 3);
		jkSetTarget(victim);
	}

	// If we did not find a good target during this pulse, then we may have lost sight of a good target from the previous pulse.
	else jkEndTarget();		// So remove the reticle.

Return;
#----------------------------------------------------------------
deactivated:
	SetPulse(0);	// Stop the pulse message.

	// If we don't have a target or the player is dead, stop the power and quit.
	if(victim == -1 || GetThingHealth(player) < 1)
	{
		SetInvActivated(player, bin, 0);
		active=0;
		Return;
	}

	jkEndTarget();					// Remove the reticle.
	mana = GetInv(player, 14);
	if(mana < cost) Return;			// Stop here if we don't have the mana.

	// Unless we have a force surge, subtract the cost from the mana.
	if(GetInv(player, 65) != 1) ChangeInv(player, 14, -cost);
	SetBinWait(player, bin, 0.2);		// Stop this force power from being used for 0.2 seconds.

	PlayMode(player, 24);			// Play a throw animation.
	PlaySoundThing(slowSound, player, 1.0, -1, -1, 0x80);	// Play the blinding sound.

	// Create a particle stream and direct it at the target.
	dummy = CreateThingAtPosNR(cone_tpl, GetThingSector(player), VectorAdd(GetThingPos(player), '0.0 0.0 0.04'), '0.0 0.0 0.0');
	SetThingLook(dummy, VectorSub(GetThingPos(victim), GetThingPos(player)));

	if(GetThingType(victim) == 10)	// Human opponent.
	{
		SkillTarget(victim, player, bin, rank);	// Call the skill message in the other player's kyle.cog.
	}
	else							// AI opponent.
	{
		SetTimerEx(0.1, victim, GetThingSignature(victim), rank * 15);
	}

	active = 0;
	SetInvActivated(player, bin, 0);	// Remove the force power's icon.

Return;
#----------------------------------------------------------------
timer:
	target = GetSenderID();

	// Check the signature (unique ID) to make sure this is the same target.
	if(GetThingSignature(target) != GetParam(0)) Return;

	timeleft = GetParam(1) - 0.1;	// Calculate time left and return if time is up.
	if(timeleft < 0) Return;

	vel = GetThingVel(target);
	if(VectorLen(vel) > 0.1)		// If the enemy's speed is less than 0.1, then we shouldn't try to slow him down.
	{
		mass = GetThingMass(target);
		momentum = VectorScale(vel, mass);
		force = VectorScale(momentum, -0.9);
		ApplyForce(target, force);	// Apply enough force to reduce his velocity by 90%
	}

	SetTimerEx(0.1, target, GetThingSignature(target), timeleft);

Return;
#----------------------------------------------------------------
selected:
	jkPrintUNIString(player, bin);		// Make sure the 27'th UNI string reads "Force Slow."

Return;
#----------------------------------------------------------------
killed:
	SetPulse(0);
	SetInvActivated(player, bin, 0);
	active=0;

Return;
#----------------------------------------------------------------
end