# Jedi Knight Cog Script
#
# FLOODGATE.COG
#
# This was writen for ZOOIKes for APT 5, one of the puzzles in it.
# 
# [DP]
#

symbols

thing       rotator
thing       floodgate
thing       floodgate1
thing       floodgate2
thing       floodgate3
thing       floodgate4
thing       lever
thing       destroy

int         time=0                           local
int         allopen=0                        local
int         i                                local
int         rotation                         local
int         active                           local

flex        speed
flex        reset
flex        rotationSpeed
flex        leverSpeed
flex        flowSpeed

sector      water
sector      water1
sector      water2
sector      water3
sector      water4

surface     flow
surface     flow1
surface     flow2
surface     flow3
surface     flow4

sound       jammed

message     startup
message     activated
message     arrived
message     timer

end                                                                           

# ========================================================================================

code
startup:
   For(i=0; i<=4; i=i+1) SetSurfaceGeoMode(flow, 4);     // Backup, can be removed if wanted
   rotation = 0;     // If it gets restarted

# ........................................................................................

activated:
   If(GetSenderRef() == rotator) 
   {
      If(active) return;
      RotatePivot(rotator, 0, rotationSpeed);
      rotation = 1;
      active = 1;
      time = time + 1;      // Trust me on this, it may seem like it won't work, but it will 
      If(time < 6)
      {
         MoveToFrame(floodgate[time - 1], 1, speed);
         If(time == 5) allopen = 1;
      }
      Else
      {
         allopen = 0;
         Time = 0;
         For(i=0; i<=4; i=i+1) MoveToFrame(floodgate, 0, speed);
      }
   }
   If(GetSenderRef() == lever)
   {
      MoveToFrame(lever, 1, leverSpeed);
      SetTimer(reset);     // Timer that moves the lever to frame one after a defined time
      If(!allopen) PlaySoundLocal(jammed, 1, 0, 0x0);
      Else
      {
         For(i=0; i<=4; i=i+1)
         {
            SetSectorFlag(water, 0x2);
            SetSurfaceGeoMode(flow, 4);     // Makes surface appear, they aren't translucent
            SlideWall(flow, '0 1 0', flowSpeed);
            DestroyThing(destroy);
         }
      }
   }
   Return;

# ........................................................................................

timer:
   MoveToFrame(lever, 0, leverSpeed);     // It's simpler this way
   Return;

# ........................................................................................

arrived:
   If(rotation == 0) Return;
   RotatePivot(rotator, 0, rotationSpeed);
   rotation = rotation + 1;
   If(rotation == 3)
   {
      rotation = 0;
      active = 0;
   }
   Return;

end

# Jedi Knight Cog Script
#
# FLOODGATE.COG
#
# This was writen for ZOOIKes for APT 5, one of the puzzles in it.
#
# [DP + SM]
#==============================================================#
symbols

thing     rotator
thing     floodgate
thing     floodgate1
thing     floodgate2
thing     floodgate3
thing     floodgate4
thing     lever
thing     destroy

int       i             local
int       done=0        local
int       active=0      local
int       time=0        local

flex      gateSpeed
flex      resetTime
flex      leverSpeed
flex      flowSpeed
flex      rotateTime

sector    water
sector    water1
sector    water2
sector    water3
sector    water4

surface   flow
surface   flow1
surface   flow2
surface   flow3
surface   flow4

vector    rotvel
vector    flowMoveVec

sound     jammed

message   activated
message   timer

end
#==============================================================#
code
#------------------------------------------------------
activated:
	if(GetSenderRef() == rotator)
	{
		if(active) Return;
		active = 1;
		SetThingRotVel(rotator, rotvel);	// start turning the rotator
		SetTimerEx(rotateTime, 2, 0, 0);	// set a timer to stop it later.
		Sleep(rotateTime / 2);	// Don't start the floodgates yet.
		if(time < 6) MoveToFrame(floodgate[time], 1, gateSpeed);
		else
		{
			time = 0;
			for(i = 0; i < 5; i = i + 1) MoveToFrame(floodgate, 0, gateSpeed);
		}
		time = time + 1;
	}
	else if(GetSenderRef() == lever)
	{
		if(time != 5)
		{
			PlaySoundLocal(jammed, 1, 0, 0x0);
			Return;
		}
		if(!done)
		{
			done = 1;
			MoveToFrame(lever, 1, leverSpeed);
			SetTimerEx(resetTime, 1, 0, 0);
			for(i = 0; i < 5; i = i + 1)
			{
				SetSectorFlags(water, 0x2);
				SetFaceGeoMode(flow, 4);
				SlideWall(flow, flowMoveVec, flowSpeed);
			}
			if(destroy > 0) DestroyThing(destroy);
		}
	}

Return;
#------------------------------------------------------
timer:
	if(GetSenderID() == 1) MoveToFrame(lever, 0, leverSpeed);
	else if(GetSenderID() == 2)
	{
		SetThingRotVel(rotator, '0 0 0');
		active = 0;
	}

Return;
#------------------------------------------------------
end