# multifloorelev.cog
#
# A cog to manage an elevator moving between multiple floors. There
# are three switches at each floor - one for up, down, and call. The
# elevator must stop to recieve a new move command.
#
# The elevator itself is expected to have a frame on each floor. Frame 0
# should be the bottom-most floor.
#
# There are two doors at each floor. They are assumed to have two frames.
# frame 0 is the closed position, and frame 1 is open. A floor's set of doors
# will stay open as long as the elevator is on that floor. Each floor is expected
# to have one door from the doorA0 array and one door from the doorB0 array.
#
# This cog as it is supports five floors. It could be modified to use more
# by simply adding more variables - remember to update the linkid.
#
# The numFloors variable tells the cog how many floors you plan to use in
# your level. This is used to prevent the cog from trying to move the elevator
# up to a floor that doesn't exist.
#
# [SM]
#==============================================================#
symbols

message   activated
message   arrived
message   timer

thing     elevator             linkid=30
thing     doorA0               nolink
thing     doorA1               nolink
thing     doorA2               nolink
thing     doorA3               nolink
thing     doorA4               nolink
thing     doorB0               nolink
thing     doorB1               nolink
thing     doorB2               nolink
thing     doorB3               nolink
thing     doorB4               nolink

surface   call0                linkid=0
surface   call1                linkid=1
surface   call2                linkid=2
surface   call3                linkid=3
surface   call4                linkid=4
surface   up0                  linkid=10
surface   up1                  linkid=11
surface   up2                  linkid=12
surface   up3                  linkid=13
surface   up4                  linkid=14
surface   down0                linkid=20
surface   down1                linkid=21
surface   down2                linkid=22
surface   down3                linkid=23
surface   down4                linkid=24

int       numFloors
int       id                   local
int       floor                local

flex      elevspeed=8
flex      doorspeed=5

sound     nudge=lvrclik1.wav

end
#==============================================================#
code
#------------------------------------------------------
activated:
	// if the elevator is moving, return.
	if(IsThingMoving(elevator)) Return;
	id = GetSenderID();
	if(id >= 0 && id < 10)
	{
		// return if elev is already at the floor.
		if(floor == id) Return;
		floor = id;
	}
	else if(id >= 10 && id < 20)
	{
		id = id - 10;
		// if the up switch was pressed while the elev
		// was on another floor, return. Or if this is the
		// top-most up switch, return because you can't
		// go higher.
		if(GetCurFrame(elevator) != id || id >= numFloors - 1) Return;
		floor = id + 1;
	}
	else if(id >= 20 && id < 30)
	{
		id = id - 20;
		// if the up switch was pressed while the elev
		// was on another floor, return. Or if this is the
		// down switch for the first floor, return.
		if(GetCurFrame(elevator) != id || id <= 0) Return;
		floor = id - 1;
	}

	// send the elevator to the floor.
	MoveToFrame(elevator, floor, elevspeed);

	// set whatever switch was activated to cel 1.
	SetWallCel(GetSenderRef(), 1);

	// play an activation sound at the switch.
	PlaySoundPos(nudge, GetSurfaceCenter(GetSenderRef()), 1, -1, -1, 0);

Return;
#------------------------------------------------------
arrived:
	if(GetCurFrame(elevator) != floor) Return;

	// open this floor's set of doors.
	MoveToFrame(doorA0[floor], 1, doorspeed);
	MoveToFrame(doorB0[floor], 1, doorspeed);
	SetTimerEx(1, 0, floor, 0);

	// turn off all switches that could have called/sent the elev.
	SetWallCel(call0[floor], 0);
	SetWallCel(up0[floor - 1], 0);
	SetWallCel(down0[floor + 1], 0);

Return;
#------------------------------------------------------
timer:
	// Wait longer if elevator is still on the same floor.
	if(floor == GetParam(0))
	{
		SetTimerEx(1, 0, GetParam(0), 0);
		Return;
	}

	// close the doors.
	MoveToFrame(doorA0[GetParam(0)], 0, doorspeed);
	MoveToFrame(doorB0[GetParam(0)], 0, doorspeed);

Return;
#------------------------------------------------------
end