# boss.cog
#
# Control cog for a level boss.
#
# Variables:
#
# switch
#	This switch, when activated, will disable the boss.
#
# spawnGhost
#	A ghost at which the boss will be created.
#
# bossTemp
#	The template for the boss thing.
#
# weapBeam
#	The boss's weapon.
#
# fireSound
#	The sound played when the boss fires.
#
# startWait
#	The length of time before the boss is created.
#
# randBeamRate
#	The rate at which the boss will fire bursts of random
#	projectiles.
#
# homeBeamRate
#	The rate at which the boss will fire a homed projectile. This
#	should be a multiple of the randBeamRate so that the homed
#	weapon will be fired with the burst of random projectiles.
#
# isWeapInstant
#	If you're using a weapon that reaches its destination almost
#	instantly, then set this to 1. Otherwise, leave it at 0.
#
# numRandBeams
#	The number of random projectiles to be fired in a burst.
#
# [GBK + ZI + SM]
#==============================================================#
symbols

message   startup
message   pulse
message   timer
message   activated

surface   switch

thing     spawnGhost
thing     player          local
thing     weapon          local
thing     boss            local

vector    vec             local
vector    veldif          local
vector    moved           local
vector    meetpos         local
vector    lvec            local

template  bossTemp
template  weapBeam

sound     fireSound

flex      startWait
flex      randBeamRate
flex      homeBeamRate
flex      speed           local
flex      distance        local
flex      time            local

int       isWeapInstant
int       numRandBeams
int       i               local
int       disabled=0      local

keyframe  standKey
keyframe  fireKey

end
#==============================================================#
code
#------------------------------------------------------
startup:
	player = GetLocalPlayerThing();
	Sleep(startWait);
	boss = CreateThing(bossTemp, spawnGhost);
	DestroyThing(spawnGhost);
	PlayKey(boss, standKey, 1, 0);
	SetPulse(0.1);
	SetTimerEx(randBeamRate, 1, 0, 0);
	SetTimerEx(homeBeamRate, 3, 0, 0);

Stop;
#------------------------------------------------------
pulse:
	AISetLookPos(boss, GetThingPos(player));

Stop;
#------------------------------------------------------
timer:
	if(GetSenderID() == 1)
	{
		if(HasLOS(boss, player)) for(i = 0; i < numRandBeams; i = i + 1) SetTimerEx(Rand(), 2, 0, 0);
		SetTimerEx(randBeamRate, 1, 0, 0);
	}
	else if(GetSenderID() == 2)
	{
		if(!isWeapInstant)
		{
			weapon = FireProjectile(boss, weapBeam, fireSound, -1, '0 0 0', '0 0 0', 0, 0x0, 0, 0);
			vec = VectorNorm(VectorSet(Rand() * 2 - 1, Rand() * 2 - 1, Rand() * -2 + 1));
			speed = VectorLen(GetThingVel(weapon));
			SetThingLook(weapon, vec);
			SetThingVel(weapon, VectorScale(vec, speed));
		}
		else
		{
			weapon = FireProjectile(boss, weapBeam, fireSound, -1, '0 0 0', '0 0 0', 0, 0x0, 0, 0);
			vec = VectorNorm(VectorSet(Rand() * 2 - 1, Rand() * 2 - 1, Rand() * -2 + 1));
			SetThingLook(weapon, vec);
		}
		PlayKey(boss, fireKey, 3, 0x38);
	}
	else if(GetSenderID() == 3)
	{
		if(HasLOS(boss, player))
		{
			if(!isWeapInstant)
			{
				weapon = FireProjectile(boss, weapBeam, fireSound, -1, '0 0 0', '0 0 0', 0, 0x0, 0, 0);
				veldif = VectorSub(GetThingVel(weapon), GetThingVel(player));
				speed = VectorLen(veldif);
				distance = VectorDist(GetThingPos(player), GetThingPos(weapon));
				time = distance / speed;
				moved = VectorScale(GetThingVel(player), time);
				meetpos = VectorAdd(GetThingPos(player), moved);
				lvec = VectorNorm(VectorSub(meetpos, GetThingPos(weapon)));
				SetThingLook(weapon, lvec);
				SetThingVel(weapon, VectorScale(lvec, VectorLen(GetThingVel(weapon))));
			}
			else weapon = FireProjectile(boss, weapBeam, fireSound, -1, '0 0 0', '0 0 0', 0, 0x20, 180, 180);
			PlayKey(boss, fireKey, 3, 0x38);
		}
		SetTimerEx(homeBeamRate, 3, 0, 0);
	}

Stop;
#------------------------------------------------------
activated:
	if(GetSenderRef() != switch || disabled) Return;
	disabled = 1;
	SetWallCel(switch, 1);
	KillTimerEx(1);
	KillTimerEx(3);
	SetPulse(0);

Stop;
#------------------------------------------------------
end

&& Getthingsector(I) == Zone|Zone1

&& (GetThingSector(i) == zone || GetThingSector(i) == zone1)