# weap_canon.cog
#
# This is a special inventory cog flagged as a weapon. When the takeWeapon
# trigger is received from class_canon, we will take control of the player's
# weapon keys by setting this cog as the weapon and forwarding the fire
# events to class_canon. This weapon's bin should look like:
#
# weap_canon   116   1  1   0x0   cog=weap_canon.cog
#
# [SM]
#==============================================================#
symbols

thing     player          local

flex      fireWait=0.5    local

int       id              local
int       i               local
int       mode            local
int       takeWeapon=76   local
int       giveWeapon=77   local
int       fireWeapon=78   local
int       ourBin=116      local
int       oldWeap         local
int       weapons         local

message   startup
message   activated
message   deactivated
message   selected
message   deselected
message   autoselect
message   fire
message   trigger

end
#==============================================================#
code
#------------------------------------------------------
startup:
	player = GetLocalPlayerThing();

Return;
#------------------------------------------------------
fire:
	mode = GetSourceRef();
	SendTrigger(-1, fireWeapon, mode, 0, 0, 0);

Return;
#------------------------------------------------------
activated:
	mode = GetSourceRef();
	ActivateWeapon(player, fireWait, mode);

Return;
#------------------------------------------------------
deactivated:
	mode = GetSenderRef();
	DeactivateWeapon(player, mode);

Return;
#------------------------------------------------------
selected:
	// not worried about models or anything
	// just set up this cog to run. What the
	// player looks like doesn't matter.
	jkClearFlags(player, 0x5);
	SetCurInvWeapon(player, ourBin);
	SetMountWait(player, 0);

Return;
#------------------------------------------------------
deselected:
	// no keys, no sounds, nothing.
	// allow the oldWeap to load immediately.
	SetMountWait(player, 0);

Return;
#------------------------------------------------------
autoselect:
	// this should only be called when we have the 0x4
	// flag. Return 1 so we can use this cog.
	ReturnEx(1);

Return;
#------------------------------------------------------
trigger:
	id = GetSourceRef();
	if(id == takeWeapon)
	{
		// assume control of the player's weapon keys
		oldWeap = GetCurWeapon(player);
		SetInvFlags(player, ourBin, 0x4);
		SetInvAvailable(player, ourBin, 1);
		call selected;
		// take away all of the player's default weapons
		weapons = HeapNew(1, 10);
		for(i = weapons; i < 11; i = i + 1)
		{
			if(IsInvAvailable(player, i)) HeapSet(i, 1);
			else HeapSet(i, 0);
			SetInvAvailable(player, i, 0);
		}
	}
	else if(id == giveWeapon)
	{
		// give the player back the weapons he had before
		for(i = weapons; i < 11; i = i + 1) SetInvAvailable(player, i, HeapGet(i));
		HeapFree();
		// give the player back his original weapon.
		SetInvFlags(player, ourBin, 0);
		SetInvAvailable(player, ourBin, 0);
		SelectWeapon(player, oldWeap);
	}

Return;
#------------------------------------------------------
end

# class_canon.cog
#
# A class cog for the cannon object.
#
# The plan: player activates canon. Real player is made invisible.
# canon gets camera focus, uses real player's attempted movement
# to move itself. actor keyframes would be good.
#
# demo templates:
#
# ghost none orient=(0.000000/0.000000/0.000000) type=ghost move=path
# ghostcam none orient=(0/0/0) type=weapon collide=1 move=physics
#	size=0.001 movesize=0.001 model3d=con0.3do
# canon none orient=(0/0/0) type=cog move=physics physflags=0x42
#	surfdrag=50 mass=200 collide=3 size=0.2 movesize=0.2
#	thingflags=0x400 model3d=canon.3do cog=class_canon.cog
#
# Don't let JED screw up your templates by making one of these the
# first template in your .jkl.
#
# [SM]
#==============================================================#
symbols

message   activated
message   deactivated
message   pulse
message   trigger

thing     ghost                    local
thing     fired                    local
thing     player                   local
thing     canon                    local
thing     cam                      local

vector    thrust                   local
vector    pos1                     local
vector    pos2                     local
vector    mvec                     local
vector    lvec                     local
vector    campos                   local

int       anim                     local
int       i                        local
int       takeWeapon=76            local
int       giveWeapon=77            local
int       fireWeapon=78            local
int       fireMode                 local

template  gtemp=ghost              local
template  wtemp=+bryarbolt         local
template  camtemp=ghostcam         local

sound     fireSound=pistol-1.wav   local

keyframe  stance=kystand0.key      local

end
#==============================================================#
code
#------------------------------------------------------
activated:
	player = GetLocalPlayerThing();
	canon = GetSenderRef();
	ParseArg(player, "soundclass=");
	SetCollideType(player, 0);
	SetThingFlags(player, 0x10);
	ghost = CreateThingAtPos(gtemp, GetThingSector(player), GetThingPos(player), '0 0 0');
	SetThingLook(ghost, GetThingLVec(player));
	cam = CreateThingAtPos(camtemp, GetThingSector(player), GetThingPos(player), '0 0 0');
	SetCameraFocus(0, cam);
	anim = PlayKey(player, stance, 5, 0);
	SendTrigger(-1, takeWeapon, 0, 0, 0, 0);
	SetPulse(0.01);

Return;
#------------------------------------------------------
deactivated:
	SetPulse(0);
	SetThingThrust(canon, '0 0 0');
	SetCameraFocus(0, player);
	ParseArg(player, "soundclass=ky.snd");
	SetCollideType(player, 1);
	ClearThingFlags(player, 0x10);
	DestroyThing(cam);
	for(i = 0; (GetSectorPlayerCount(GetSurfaceSector(i)) == 0 || !(GetSurfaceFlags(i) & 0x1)) && i < GetSurfaceCount(); i =i + 1);
	AttachThingToSurf(player, i);
	SetThingVel(player, '0 0 0');
	SetThingPos(player, GetThingPos(ghost));
	if(ghost != 0 && ghost != -1 && ghost != player) DestroyThing(ghost);
	SendTrigger(-1, giveWeapon, 0, 0, 0, 0);
	StopKey(player, anim, 0.5);

Return;
#------------------------------------------------------
pulse:
	SetThingRotVel(canon, GetThingRotVel(player));
	fired = FireProjectile(player, gtemp, -1, -1, '0 0 0', '0 0 0', 0, 0x0, 0, 0);
	lvec = GetThingLVec(fired);
	DestroyThing(fired);
	SetThingLook(canon, lvec);
	thrust = GetThingThrust(player);
	SetThingThrust(canon, thrust);
	SetThingPos(player, GetThingPos(ghost));
	if(!(GetAttachFlags(player) & 0x1) || VectorZ(thrust) > 0) call deactivated;
	if(GetCurrentCamera() != 0) CycleCamera();
	pos1 = VectorAdd(GetThingPos(canon), VectorSet(0, 0, 0.3));
	pos2 = VectorScale(VectorNorm(GetThingLVec(canon)), -0.4);
	lvec = VectorSub(GetThingPos(canon), GetThingPos(cam));
	campos = VectorAdd(pos2, pos1);
	mvec = VectorSub(campos, GetThingPos(cam));
	SetThingVel(cam, VectorScale(mvec, 6));
	SetThingLook(cam, lvec);
	if(!HasLOS(cam, canon)) TeleportThing(cam, canon);
	if(VectorDist(GetThingPos(canon), GetThingPos(cam)) > 4) TeleportThing(cam, canon);

Return;
#------------------------------------------------------
trigger:
	if(GetSourceRef() == fireWeapon)
	{
		fireMode = GetParam(0);
		FireProjectile(canon, wtemp, fireSound, -1, '0 0.02 0.02', '0 0 0', 1, 0, 0, 0);
	}

Return;
#------------------------------------------------------
end