##########################################################
# Jedi Knight Cog Script  (JK)
#---------------------------------------------------------
# LOBBY_TELE01.COG
# -RED_SWITCH is disabled when activated.
# -GOLD_SWITCH can be used as many times as needed.
# -Teleports the player that activates the switch to a
#  ghost, changes his model, team, and spawn points.
#---------------------------------------------------------
# Written By DSLS_DeathSythe
# This COG is NOT supported by LucasArts Entertainment Co.
##########################################################
symbols
#---------------------------------------------------------
message     startup
message     activated
message     join
message     timer
#--------------------#
surface     red_switch=-1
surface     gold_switch=-1

model       red_mdl=kyX0.3DO
model       gold_mdl=kyU0.3DO

thing       red_start=-1                                  nolink
thing       gold_start=-1                                 nolink
#--------------------#
thing       player=-1                                     local
thing       senderRef=-1                                  local

template    teleport_particles=+telesparks                local
sound       teleport_snd=ForceThrow01.WAV                 local
sound       act_snd=activate01.WAV                        local
sound       click_snd=lgclick1.WAV                        local

thing       dummy=-1                                      local

int         is_on=0                                       local
#---------------------------------------------------------
end
#=========================================================
code
#---------------------------------------------------------
startup:
	player = GetLocalPlayerThing();

	//-SERVER ONLY startup:
	if(IsServer() || !IsMulti())
		{
		//-Team mode                   (1)
		//-No damage to teammates      (2)
		//-No custom costumes         (20)
		SetMultiModeFlags(0x23);

		//-Auto assign teams          (100)
		//-This also disallows the command to change teams
		ClearMultiModeFlags(0x100);

		//-Because team mode might have assigned the server player to team 1
		SetPlayerTeam(player, 0);

		is_on = 0;
		}

	//-CTF Team
	SetPlayerTeam(player, 0);

	//-The player can only spawn on 16 to 31 the first time
	SetRespawnMask(player, 0x0000FFFF);
return;
#---------------------------------------------------------
join:
	player = GetSenderRef();
	SetPlayerTeam(player, 0);
	//-The player can only spawn on 16 to 31 the first time
	SetRespawnMask(player, 0x0000FFFF);
return;
#---------------------------------------------------------
activated:
	//-Exit if activated: was sent by anything else than a surface
	if(GetSenderType() != 6) return;

	player = GetSourceRef();
	senderRef = GetSenderRef();

	//-These are the Team selection surfaces.
	//-The player is marked with the correct color, then teleported into the game.

	//-This switch is disabled once it has been activated.
	if(senderRef == red_switch)
		{
		//-If the switch has already been used dont let any one else use it.
		if(is_on == 1)
			{
			PlaySoundPos(click_snd, GetSurfaceCenter(red_switch), 1.0, -1, -1, 0x0);
			return;
			}
		is_on = 1;
		SetWallCel(red_switch, 1);
		PlaySoundPos(act_snd, GetSurfaceCenter(red_switch), 1.0, -1, -1, 0x0);

	      SetPlayerTeam(player, 1);

		// Give the player a red costume
		SetThingModel(player, red_mdl);

		AddDynamicTint(player, 0.0, 0.75, 0.0);
		StopThing(player);
		TeleportThing(player, red_start);
		dummy = CreateThing(teleport_particles, player);
		PlaySoundThing(teleport_snd, player, 1.0, -1, -1, 0x80);

		// spawnpoints 0 to 7 are RED, so it is 0xFFFFFF00
		SetRespawnMask(player, 0xFFFFFF00);
		return;
		}
	else
	if(senderRef == gold_switch)
		{
		SetWallCel(gold_switch, 1);
		SetTimer(1.0);
		PlaySoundPos(act_snd, GetSurfaceCenter(gold_switch), 1.0, -1, -1, 0x0);

		SetPlayerTeam(player, 2);

		// Give the player a gold costume
		SetThingModel(player, gold_mdl);

		AddDynamicTint(player, 0.0, 0.75, 0.0);
		StopThing(player);
		TeleportThing(player, gold_start);
		dummy = CreateThing(teleport_particles, player);
		PlaySoundThing(teleport_snd, player, 1.0, -1, -1, 0x80);

		// spawnpoints 8 to 15 are GOLD, so it is 0xFFFF00FF
		SetRespawnMask(player, 0xFFFF00FF);
		return;
		}
return;
#---------------------------------------------------------
timer:
	SetWallCel(gold_switch, 0);
return;
##########################################################
end