# daft_healer.cog
#
# By Emon, August 2005
#
# Some healing switch for one of Daft Vader's levels.
#
#==============================================================================
symbols
 
thing       switch
sound       sound
flex        delay=5
flex        health=10.0
flex        shields=5.0
flex        volume=1.0
flex        sndMinRad
flex        sndMaxRad
 
int         disabled=0          local
int         channel             local
flex        oldHealth           local
flex        newHealth           local
flex        healthDiff          local
thing       player              local
 
message     activated
message     timer
 
end
#==============================================================================
code
 
#------------------------------------------------------------------------------
activated:
    if(disabled == 1)
        return;
    disabled = 1;
    setTimer(delay);
 
    player = getSourceRef();
    channel = playSoundThing(sound, switch, volume, sndMinRad, sndMaxRad, 0x0);
 
    oldHealth = getThingHealth(player);
    healThing(player, 10000000000000);
    newHealth = getThingHealth(player);
    setThingHealth(player, oldHealth);
    healthDiff = newHealth - oldHealth;
    healThing(player, health);
 
    if(oldHealth == newHealth)
        changeInv(player, 60, shields);
    else
        changeInv(player, 60, healthDiff * (shields/health));
 
    return;
 
timer:
    disabled = 0;
    return;
 
end

# Jedi Knight Cog Script
#
# EASY_LITTLE_COG.COG
#
# Tiny Script - Easy Little Cog
#
# 8/24/05 by ReT for Daft_Vader
#
# ========================================================================================

symbols

sound       YourSound=BactaUse01.WAV              local // Whatever you want
thing       player
flex        pause=5
message	    activated
message     timer 


end

# ========================================================================================

code

activated:
   player = GetLocalPlayerThing();
   
   PlaySoundThing(YourSound, player, 1.0, -1, -1, 128);

   if(disabled == 1) 
   {
      Return;
   }
    
   disabled = 1;
   setTimer(pause);

   // If the player health is already max...
   if(GetThingHealth(player) == 100) 
   {
      // Give him 5 shields
      Print("Giving Player 5 Shields...");
      ChangeInv(player, 60, 5);
   }
   else
   {
      // If not...
      Print("Giving the Player 10 Health...");
      HealThing(player, 10.0);
   }

   Return;

# ----------------------------------------------------------------------------------------

timer:
   disabled = 0;
   Return;
 
end

# Jedi Knight Cog Script
#
# daft_glass.COG
#
# Breaking glass for Daft Vader.
#
# Note: the template used is shard00, NOT shard0!
#
# [YB]
#
# (C) 1997 LucasArts Entertainment Co. All Rights Reserved
#==============================================================#
symbols

surface   glass                         mask=0x448 desc=glass
surface   glass2                        mask=0x448 desc=glass_adjoin

sound     dialogue
flex      dialogue_volume
sound     alarm
flex      alarm_volume
flex      alarm_minRad
flex      alarm_maxRad
flex	  alarm_delay
sound     glass_break=GlassBreak1.WAV   local

sector	  tint_sector
vector    tint_rgb

thing     door1
thing     door2
flex	  door_speed

vector	  orig_tint						local
flex	  z								local

vector    surface_center                local
vector    vertex                        local
vector    where                         local

int       spawnpoints=2                 desc=spawn_points
int       density=5                     desc=density
int       surface_sector                local
int       surface_vertices              local
int       i                             local
int       j                             local
int		  n								local
flex      k                             local
int       a_shard                       local
int       dummy                         local
int       disabled=0                    local

template  shard_tpl=shard00             local

message   damaged
message   pulse
message   timer

end
#==============================================================#
code
#------------------------------------------------------
damaged:
	if(!disabled)
	{
		disabled = 1;
		// Add 10 cm along the normal to solve some rounding error or non planar face...
		surface_center = VectorAdd(SurfaceCenter(GetSenderRef()), VectorScale(GetSurfaceNormal(GetSenderRef()), 0.01));
		surface_sector = GetSurfaceSector(GetSenderRef());
		surface_vertices = GetNumSurfaceVertices(GetSenderRef());
		dummy = PlaySoundPos(glass_break, surface_center, 1.0, 10.0, 20.0, 0);
		// First spawn 'density' shards with random velocities at the center of the face.
		for(k = 0; k < density; k = k + 1)
		{
			a_shard = CreateThingAtPos(shard_tpl, surface_sector, surface_center, '0.0 0.0 0.0');
			SetThingVel(a_shard, VectorSet(1.4 * (Rand() - 0.5), 1.4 * (Rand() - 0.5), 1.4 * (Rand() - 0.5) + 0.75));
			SetThingRotVel(a_shard, VectorSet(500 * (Rand() - 0.5), 500 * (Rand() - 0.5), 500 * (Rand() - 0.5)));
		}
		// Then spawn 'density' shards with random velocities at 'spawnpoints' points
		// between the center of the face and the face's vertices.
		for(i = 0; i < surface_vertices; i = i + 1)
		{
			vertex = GetSurfaceVertexPos(glass, i);
			for(j = 1; j <= spawnpoints; j = j + 1)
			{
				where = VectorAdd(surface_center, VectorScale(VectorSub(surface_center, vertex), j / (spawnpoints + 1)));
				for(k = 0; k < density; k = k + 1)
				{
					a_shard = CreateThingAtPos(shard_tpl, surface_sector, where, '0.0 0.0 0.0');
					SetThingVel(a_shard, VectorSet(1.4 * (Rand() - 0.5), 1.4 * (Rand() - 0.5), 1.4 * (Rand() - 0.5) + 0.75));
					SetThingRotVel(a_shard, VectorSet(500 * (Rand() - 0.5), 500 * (Rand() - 0.5), 500 * (Rand() - 0.5)));
				}
			}
		}
		SetFaceGeoMode(glass, 0);	// GEOMETRY_NONE
		SetFaceGeoMode(glass2, 0);
		SetAdjoinFlags(glass, 2);	// Set ADJOIN_MOVE  (allow passage)
		SetAdjoinFlags(glass2, 2);
		
		PlaySoundGlobal(dialogue, dialogue_volume, 0, 0x0);
		moveToFrame(door1, 1, door_speed);
		moveToFrame(door2, 1, door_speed);
		i = 0;
		j = 0;
		orig_tint = getSectorTint(tint_sector);
		setPulse(0.01);
	}

Return;
#------------------------------------------------------
pulse:
	setSectorTint(tint_sector, tint_rgb);
	setTimer(0.001);
	playSoundPos(alarm, surface_center, alarm_volume, alarm_minRad, alarm_maxRad, 0x0);
	if(i == 2)
	{
		setPulse(0);
		sleep(getSoundLen(alarm));
		setTimer(0);
		setSectorTint(tint_sector, orig_tint);
		return;
	}
	i = i + 1;
	setPulse(getSoundLen(alarm) + alarm_delay);
	return;

timer:
	setSectorTint(tint_sector, vectorScale(getSectorTint(tint_sector), 0.95));
	setTimer(0.001);
	return;
	
end