##########################################################
# Jedi Knight Cog Script  (JK)
#---------------------------------------------------------
# 00_SMOKETRAIL.COG
# -Leaves a smoke trail behind a moving object.
# -Allows the player to have control of the raildet
#  and makes it a player guided missle
#---------------------------------------------------------
# Modified version of LEC's 00_smoketrail.cog
# Written By DSLS_DeathSythe
# This COG is NOT supported by LucasArts Entertainment Co.
##########################################################
flags=0x240
symbols
#---------------------------------------------------------
message     startup
message     created
message     removed
message     pulse
#--------------------#
thing       player=-1                        local
thing       rocket=-1                        local

thing       temp_thng=-1                     local
template    temp_tpl=+repeaterball           local

template    smoke=+smoke                     local
thing       dummy=-1                         local
int         smoke_count=0                    local

vector      old_lookVec                      local
int         old_camera=0                     local
int         count=0                          local

vector      look_dir                         local
flex        y_dir=0.0                        local
flex        z_dir=0.0                        local
flex        yaw_max=100.0                    local
flex        pitch_max=100.0                  local
#---------------------------------------------------------
end
#=========================================================
code
#---------------------------------------------------------
startup:
	player = GetLocalPlayerThing();
	rocket = -1;
return;
#---------------------------------------------------------
created:
	//-Only one rocket at time.
	//-If there is already one going, destroy it and
	// send the new one in the right direction.
	if(rocket != -1)
		{
		SetLifeLeft(rocket, 0.1);
		StopThing(GetSenderRef());
		SetThingLook(GetSenderRef(), old_lookVec);
		SetThingVel(rocket, VectorScale(GetThingLVec(rocket), 2));
		}
	else
		{
		old_lookVec = GetThingLVec(player);
		old_camera = GetCurrentCamera();
		}
	rocket = GetSenderRef();

	//-Let the rocket fly for 30 seconds...
	SetLifeLeft(rocket, 30.0);

	//-set 100 msec timer for smoke release and control stuff
	SetThingPulse(rocket, 0.01);

	//-Stop the rockets spinning...
//	ParseArg(rocket, "angvel=(0.0/0.0/0.0)");
	SetThingRotVel(rocket, '0 0 0');
	SetWeaponFlags(rocket, 0x100);

	//-Stop the players movements, center his view on the Y axis,
	// and adjust the min and max headpitch...
	SetActorFlags(player, 0x40002);
	SetThingLook(player, '0 1.0 0');
	ParseArg(player, "minheadpitch=-90.00");
	ParseArg(player, "maxheadpitch=90.00");

	//-If the player isnt in internal view, switch cameras
	if(old_camera != 0) CycleCamera();
	SetCameraFocus(0, rocket);
	count = 0;
return;
#---------------------------------------------------------
removed:
	//-If its not the currently controlled rocket then ignore it...
	if(GetSenderRef() != rocket) return;

	//-Else reset all the players stuff...
	ClearActorFlags(player, 0x40000);
	SetCameraFocus(0, player);
	if(GetCurrentCamera() != old_camera) CycleCamera();
	SetThingLook(player, old_lookVec);
	SetActorFlags(player, 0x2);
	ParseArg(player, "minheadpitch=-80.00");
	ParseArg(player, "maxheadpitch=80.00");
	rocket = -1;
return;
#---------------------------------------------------------
pulse:
	//-Dont let the smoke come out every pulse...
	smoke_count = smoke_count + 1;
	if(smoke_count >= 5)
		{
		//-create smoke at our current location
		dummy = CreateThing(smoke, GetSenderRef());
		smoke_count = 0;
		}

	//-Small delay before we take control of the rocket...
	if(count < 10)
		{
		count = count + 1;
		return;
		}
	else
		{
		//-Limit the players YAW movements...
		look_dir = GetThingLVec(player);
		if(VectorX(look_dir) > 0 && VectorY(look_dir) < 0)
			SetThingLook(player, '1.0 0 0');
		if(VectorX(look_dir) < 0 && VectorY(look_dir) < 0)
			SetThingLook(player, '-1.0 0 0');

		//-Get the playes true look vector...
		temp_thng = FireProjectile(player, temp_tpl, -1, -1, '0 0 0', '0 0 0', 1.0, 0x0, 0.0, 0.0);
		StopThing(temp_thng);
		SetLifeLeft(temp_thng, 0.02);
		SetThingFlags(temp_thng, 0x80000);
		look_dir = GetThingLVec(temp_thng);

		//-Adjust the rockets look by the players look_dir...
		y_dir = VectorX(GetThingLVec(player)) * -yaw_max;
		z_dir = VectorZ(look_dir) * pitch_max;
		look_dir = VectorSet(z_dir, y_dir, 0.0);
		SetThingRotVel(rocket, look_dir);
		SetThingVel(rocket, VectorScale(GetThingLVec(rocket), 2));
		}
return;
##########################################################
end