# Flickering Neon Light
#
# By Edward
symbols

message       startup
message       pulse

thing       light
surface       bulb

flex       highlight
flex       lowlight
flex       maxon
flex       minon
flex       maxoff
flex       minoff
# These flexes determine how long the light should be on and off.
# With this, you have free choice on how old the bulb is,
# or how random it should flicker.

sound       zap
sound       blink

end
#
code
startup:
   sleep(1);
   SetPulse(minon+rand()*maxon);
return;
pulse:
   if(GetThingLight(light)<highlight)
   {
      ThingLight(light, highlight, 0.1);
      PlaySoundThing(blink,light, 1, -1, -1, 0x80);
      SetSurfaceLight(bulb, highlight, 0.1);
      SetPulse(minon+rand()*maxon);
   }
   else if(GetThingLight(light)>lowlight)
   {
      ThingLight(light, lowlight, 0.1);
      PlaySoundThing(zap, light, 1, -1, -1, 0x80);
      SetSurfaceLight(bulb, lowlight, 0.1);
      SetPulse(minoff+rand()*maxoff);
   }
return;
end 

# Jedi Knight Cog Script
#
# Flickering Lights
# 
# [darthslaw]
# 
# This Cog is Not supported by LucasArts Entertainment Co

symbols

message		startup
message		activated
message		pulse

surface		switch
thing		light

int		on=0				# set to 0 if you want lights off on startup, and 1 if you want them on

flex		mindelay=0.1			# delay between on/off flickering
flex		maxdelay=1.0
flex		minlight=0.1			# min light to be emitted
flex		maxlight=0.7			# max light to be emitted
flex		offlight=0.0			# how much light should be emitted when the light is off

sound		flipswitch=lvrclik1.wav		# when switch is nudged
sound		flicker=forcefieldhit01.wav	# when light flickers

flex		L=0				local

end

# ========================================================================================

code

startup:
	sleep(0.1);
	if(!on)	SetThingLight(light, offlight, 0.0);
	else SetPulse(mindelay + rand() * (maxdelay - mindelay));
	SetWallCel(switch, on);
	Return;

Pulse:
	L = 1 - L;
	if(L) SetThingLight(light, minlight, 0.0);
	else
	{
		SetThingLight(light, maxlight, 0.0);
		PlaySoundThing(flicker, light, 0.5, -1, -1, 0x80);
	}
	SetPulse(mindelay + rand() * (maxdelay - mindelay));
	Return;

Activated:
	if(GetSenderRef() != switch) return;
	on = 1 - on;
	L = 0;
	SetWallCel(switch, on);
	PlaySoundPos(flipswitch, SurfaceCenter(switch), 1.0, -1, -1, 0x0);
	if(on) SetPulse(0.01);
	else
	{
		SetPulse(0);
		SetThingLight(light, offlight, 0.0);
	}
	Return;

# ........................................................................................

end