symbols

keyframe      	animation

sound		fire_sound

vector		force

thing		catapult
thing		fire_ghost
thing		player			local

flex		max_dist=0.1
flex		dist_temp		local
flex		fire_sound_dist=2

int		firing			local

message		startup
message		entered
message		trigger

end

code

startup:
	// Initialize control variables
	firing = 0;
	Return;

entered:
	// Return if another firing process is in the works
	if(firing)
		Return;

	// Determine distance from toucher to fire_ghost
	dist_temp = VectorDist(GetThingPos(GetSourceRef()), GetThingPos(fire_ghost));
	// Only process positive distances
	if(dist_temp < 0)
		dist_temp = dist_temp * -1;
	// Check if toucher is within range of fire_ghost
	if(dist_temp - max_dist < 0)
		SendTrigger(-1, 133799, GetPlayerNum(GetSourceRef()), -1, -1, -1);

	Return;

trigger:
	if(GetSourceRef() == 133799)
	{
		player = GetPlayerThing(GetParam(0));

		// Activate the catapult
		firing = 1;

		// Detach the player from the catapult
		DetachThing(player);

		// Shoot the player
		ApplyForce(player, force);

		// Display the fire animation
		PlayKey(catapult, animation, 0, 0x2);

		// Play the fire sound
		PlaySoundThing(fire_sound, catapult, 1.6, 0, fire_sound_dist * 10.5, 0x80);

		// Wait until animation has stopped
		Sleep(GetKeyLen(animation));

		// Deactivate catapult
		firing = 0;
	}

	Return;

end

# RopeClimb.cog
#
#
# Jedi Knight Cog Script
#
# This cog controls a 3do climbing rope
# Walk up to the rope and jump then use walk to climb up the rope
#
# Jedi I 2006
# concept from Tom Smallwood's ladder.cog
#
#-------------------------------------------------------------------------------------------------------------------------------

symbols

message	touched
message	pulse

thing		rope		

int		climbing	local
int		player	local

end

#-------------------------------------------------------------------------------------------------------------------------------

code

touched:  // start climbing the rope

	player=getsourceref();

	if(climbing==1)	return;

	if(getsenderref()!=rope)	return;

	if(getsenderref()==rope)	// if player touches the rope then let them climb up

		{
	
		detachthing(player);	// detach player from floor

		ClearPhysicsFlags(player, 0x1);	// change player's physics properties to allow them to walk up the rope

		SetPhysicsFlags(player, 0x2802);

		attachthingtothing(player,rope);	// attach player to rope 

		climbing=1;	// player is climbing the rope

		setpulse(0.5);

		}

	return;

#-------------------------------------------------------------------------------------------------------------------------------


pulse:	//prevent the player from floating up


	stopthing(player);

	if(getthingattachflags(player)== 0x0) // check if player is still attached to rope

		{

		ClearPhysicsFlags(player, 0x2800);
		
		SetPhysicsFlags(player, 0x1);
		
		detachthing(player);
		
		climbing=0;

		setpulse(0);

		}
	
return;

end